/*Published: 11/1/2017*/
/************************************************************************/
/* IF YOU RECEIVED THE SUMDENOM FILE BEFORE NOVEMBER 2017 THEN YOU WILL */
/* NEED A DIFFERENT INPUT STATEMENT. PLEASE CONTACT IMS VIA E-MAIL      */
/* SEER-MEDICARE@IMSWEB.COM AND AN INPUT STATEMENT WILL BE SENT TO      */
/* YOU.                                                                 */
/* This input statement is used to read in the sumdenom.nonSEER.txt     */
/* file.                                                                */
/************************************************************************/

*filename sumin '/directory/sumdenom.nonSEER.txt';                   /*reading in an un-zipped file*/
filename sumin pipe 'gunzip -c /directory/sumdenom.nonSEER.txt.gz';  /*reading in a zipped file*/

options nocenter validvarname=upcase;

data sumden(drop=i begin end inc3 p inc2);
  infile sumin lrecl=1387 missover pad;
  input @0001  pHIC      $char11.
        @0012  birthm    $char2.
        @0014  birthd    $char2.
        @0016  birthyr   $char4.
        @0021  med_dodm  $char2.
        @0023  med_dodd  $char2.
        @0025  med_dody  $char4.
        @0029  m_sex     $char1.                   
        @0030  race      $char1.
        @0031  rsncd1    $char1.
        @0032  cur_ent   $char1.
        @0033  cur_yr    $char4.                   
        @0037  chr_esrd  $char1.
        @0038  chr_esrd_yr $char4.                 
        @0042  first_esrd_yr $char4.
        @0046  med_stcd  $char2.
        @0048  medst_yr  $char4.                                 
        @0053  castat5   $char1.
        @0054  all_castat5 $char1.
        @0055  castat5_seerarea $char1.
        @0056  year_last_svy $char4.
        @;
      inc2=66;
      inc3=507;

      array urbancd(20)  $ 2 urban1996-urban2015;
      array urbrec(20)   $ 1 urbrur1996-urbrur2015;
      array ghon(240)    $ 1 hmo1-hmo240;
      array enmon(240)   $ 1 ent1-ent240;
      array allflag(240) $ 1 stbuy1-stbuy240;
      array enta(20)     $ 2 ptacnt1996-ptacnt2015;
      array entb(20)     $ 2 ptbcnt1996-ptbcnt2015;
      array hmoc(20)     $ 2 hmocnt1996-hmocnt2015;
      array stbuy(20)    $ 2 stbuycnt1996-stbuycnt2015;
      array state(20)    $ 2 state1996-state2015;
      array cnty(20)     $ 3 cnty1996-cnty2015;
      array zips5(20)    $ 5 enzip5_1996-enzip5_2015;
      array zips4(20)    $ 4 enzip4_1996-enzip4_2015;
      array registry(20) $ 2 registry1996-registry2015;
      array regcd2(20)   $ 2 reg2cd1996-reg2cd2015;

      do i = 1 to 20;
      input @inc2     state(i)    $char2.
            @inc2+2   cnty(i)     $char3.
            @inc2+5   zips5(i)    $char5.
            @inc2+10  zips4(i)    $char4.
            @inc2+14  urbancd(i)  $char2.
            @inc2+16  urbrec(i)   $char1.
            @inc2+17  registry(i) $char2.
            @inc2+19  regcd2(i)     $char2.
            @;
            inc2=inc2+21;
      end;
        retain begin end;
        begin=1;
        end=12;

      do i = 1 to 20;
        do p = begin to end;
           input @inc3      enmon(p)   $char1.
                 @inc3 + 12 ghon(p)    $char1.
                 @inc3 + 24 allflag(p) $char1.
                 @;
              inc3=inc3 + 1;
              end;
            begin = begin + 12;
            end = end + 12;
        input @inc3 + 24 enta(i)   $char2.
              @inc3 + 26 entb(i)   $char2.
              @inc3 + 28 hmoc(i)   $char2.
              @inc3 + 30 stbuy(i)  $char2.
              @;
             inc3=inc3 + 32;
        end;
        input;

label
  phic       = 'Protected Patient ID'
  birthm     = 'Birth Month'
  birthyr    = 'Birth Year'
  med_dodm   = 'Death Month'
  med_dody   = 'Death Year'
  med_dodd   = 'Death Day'
  m_sex      = 'Sex'
  race       = 'Race'
  rsncd1     = 'Original Reason for Entitlement'
  cur_ent    = 'Current Reason for Entitlement'
  cur_yr     = 'Current Reason for Entitlement Year'
  chr_esrd   = 'Chronic Renal Disease'
  chr_esrd_yr= 'Chronic Renal Disease Year'
  first_esrd_yr = 'First ESRD Year'
  med_stcd   = 'Medicare Status Code'
  medst_yr   = 'Year of Medicare Status Code'
  urban1996  = 'Urban/Rural Code for 1996'
  urbrur1996 = 'Urban/Rural Recode for 1996'
  registry1996= 'First Registry for 1996'
  reg2cd1996 = 'Last Registry for 1996'
  ent1       = 'PART A and B Entitlement Monthly Indicator (1=Jan 1996, 240=Dec 2015)'
  hmo1       = 'HMO Entitlement Monthly Indicator (1=Jan 1996, 240=Dec 2015)'
  stbuy1   = 'State Buy-in Monthly Indicator (1=Jan 1996, 240=Dec 2015)'
  ptacnt1996 = 'Total Months Part A Coverage'
  ptbcnt1996 = 'Total Months Part B Coverage'
  hmocnt1996 = 'Total Months HMO Coverage'
  stbuycnt1996= 'Total Months State Buy-in Coverage'
  state1996  = 'State for 1996'
  cnty1996   = 'County for 1996'
  enzip5_1996   = 'Zip Code in 1996, first 5 digits'  /* Special Permission required for unencypted zip */
  enzip4_1996   = 'Zip Code in 1996, last 4 digits'  /* Special Permission required for unencypted zip */
  castat5     = 'At least one survey has Cancer Status = 5 (not in SEER and Any Cancer = No)'
  all_castat5 = 'All Surveys for the patient have Cancer Status = 5'
  castat5_seerarea = 'At least one survey has Cancer Status = 5 and lived in a SEER area when the survey was taken'
  year_last_svy = 'Last Survey Year'
  ;

run;

proc contents data=sumden position;
run;